apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'kotlin-kapt'
apply plugin: 'realm-android'
apply plugin: 'com.google.gms.google-services' // Crashlytics
apply plugin: 'com.google.firebase.crashlytics'

repositories {
    maven { url 'https://jitpack.io' } // required for MPAndroidChart
    jcenter() // for kotlin serialization
}

android {

    compileSdkVersion 29
    buildToolsVersion "29.0.2"

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_1_8
    }

    lintOptions {
        disable 'MissingTranslation'
    }

    defaultConfig {
        applicationId "net.pokeranalytics.android"
        minSdkVersion 23
        targetSdkVersion 29
        versionCode 113
        versionName "5.1"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        debug {
            ext.enableCrashlytics = false
        }
        release {
            minifyEnabled true

            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            applicationVariants.all { variant ->
                variant.outputs.all { output ->
                    def date = new Date()
                    def formattedDate = date.format('yyMMdd_HHmm')
                    def appName = "PokerAnalytics"
                    def buildType = variant.buildType.name
                    def newName
                    if (buildType == 'debug'){
                        newName = "${appName}_${defaultConfig.versionName}(${defaultConfig.versionCode})_${formattedDate}_debug.apk"
                    } else {
                        newName = "${appName}_${defaultConfig.versionName}(${defaultConfig.versionCode})_${formattedDate}_release.apk"
                    }
                    outputFileName = newName
                }
            }
        }
    }
    flavorDimensions 'endOfUse'
    productFlavors { // already used: 50000, 51000, 52000
        standard {
            dimension = 'endOfUse'
        }
        april2021 {
            dimension = 'endOfUse'
            versionNameSuffix = '_april2021'
            versionCode = 52130 + android.defaultConfig.versionCode
        }
        nov2020 {
            dimension = 'endOfUse'
            versionNameSuffix = '_nov2020'
            versionCode = 52110 + android.defaultConfig.versionCode
        }
        oct2021 {
            dimension = 'endOfUse'
            versionNameSuffix = '_oct2021'
            versionCode = 52120 + android.defaultConfig.versionCode
        }
    }

    configurations {
        release {
            all*.exclude group: 'com.google.guava', module: 'listenablefuture'
        }
    }

}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])

    // Kotlin
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.3.6'
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.3.6"
    implementation "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    implementation("org.jetbrains.kotlinx:kotlinx-serialization-runtime:0.20.0") // JVM dependency

    // Android
    implementation 'androidx.appcompat:appcompat:1.1.0'
    implementation 'androidx.core:core-ktx:1.3.1'
    implementation 'com.google.android.material:material:1.2.1'
    implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
    implementation 'androidx.lifecycle:lifecycle-extensions:2.2.0'
    implementation 'androidx.work:work-runtime-ktx:2.4.0'
    implementation 'com.google.android.play:core-ktx:1.8.1' // In-app Reviews

    // Places
    implementation 'com.google.android.libraries.places:places:2.3.0'

    // Billing / Subscriptions
    implementation 'com.android.billingclient:billing:3.0.1'

    // Import the Firebase BoM
    implementation platform('com.google.firebase:firebase-bom:25.12.0')
    // Add the dependency for the Firebase SDK for Google Analytics
    // When using the BoM, don't specify versions in Firebase dependencies
    implementation 'com.google.firebase:firebase-analytics-ktx'

    // Add the Firebase Crashlytics SDK.
    implementation 'com.google.firebase:firebase-crashlytics'

    // Logs
    implementation 'com.jakewharton.timber:timber:4.7.1'

    // MPAndroidChart
    implementation 'com.github.PhilJay:MPAndroidChart:v3.1.0'

    // CSV Parser: https://mvnrepository.com/artifact/org.apache.commons/commons-csv
    implementation 'org.apache.commons:commons-csv:1.7'

    // Polynomial Regression
    implementation 'org.apache.commons:commons-math3:3.6.1'

    // ffmpeg for encoding video (HH export)
    implementation 'com.arthenica:mobile-ffmpeg-min-gpl:4.4.LTS'

    // Instrumented Tests
    androidTestImplementation 'androidx.test:core:1.3.0'
    androidTestImplementation 'androidx.test:runner:1.3.0'
    androidTestImplementation 'androidx.test:rules:1.3.0'
    androidTestImplementation 'androidx.test.ext:junit:1.1.2'

    // Test
    testImplementation 'junit:junit:4.12'
    testImplementation 'com.android.support.test:runner:1.0.2'
    testImplementation 'com.android.support.test:rules:1.0.2'

    // gross, somehow needed to make the stop notif work
    implementation 'com.google.guava:guava:27.0.1-android'

}